CMakeLists.txt

project(ldforge)
cmake_minimum_required(VERSION 2.8.12)
set(CMAKE_MODULE_PATH "${CMAKE_SOURCE_DIR}/CMake")
include(cotire)
find_package(Qt5Widgets REQUIRED)
if (Qt5Widgets_VERSION VERSION_LESS 5.5.0)
	message(FATAL_ERROR "Qt5 version 5.5 required")
endif()
find_package(Qt5Core REQUIRED)
find_package(Qt5OpenGL REQUIRED)
find_package(Qt5Network REQUIRED)
find_package(Qt5LinguistTools REQUIRED)
set (CMAKE_AUTOMOC ON)
find_package(OpenGL REQUIRED)
include_directories(${QT_INCLUDES} ${CMAKE_CURRENT_BINARY_DIR})

set (LDFORGE_SOURCES
	src/documentmanager.cpp
	src/libraries.cpp
	src/main.cpp
	src/mainwindow.cpp
	src/model.cpp
	src/modeleditcontext.cpp
	src/parser.cpp
	src/version.cpp
	src/vertex.cpp
	src/objecttypes/comment.cpp
	src/objecttypes/conditionaledge.cpp
	src/objecttypes/edge.cpp
	src/objecttypes/errorline.cpp
	src/objecttypes/modelobject.cpp
	src/objecttypes/polygon.cpp
	src/objecttypes/subfilereference.cpp
	src/settingseditor/librarieseditor.cpp
	src/settingseditor/settingseditor.cpp
)
set (LDFORGE_HEADERS
	src/basics.h
	src/colors.h
	src/documentmanager.h
	src/libraries.h
	src/main.h
	src/mainwindow.h
	src/model.h
	src/modeleditcontext.h
	src/parser.h
	src/version.h
	src/vertex.h
	src/objecttypes/comment.h
	src/objecttypes/conditionaledge.h
	src/objecttypes/edge.h
	src/objecttypes/errorline.h
	src/objecttypes/modelobject.h
	src/objecttypes/polygon.h
	src/objecttypes/subfilereference.h
	src/settingseditor/librarieseditor.h
	src/settingseditor/settingseditor.h
)
set (LDFORGE_FORMS
	src/mainwindow.ui
	src/settingseditor/librarieseditor.ui
	src/settingseditor/settingseditor.ui
)

set(LDFORGE_LOCALES
	locale/fi.ts
	locale/sv.ts
	locale/ru.ts
)

set(LDFORGE_RESOURCES ldforge.qrc)

# Translations
qt5_create_translation(QM_FILES ${LDFORGE_SOURCES} ${LDFORGE_HEADERS} ${LDFORGE_FORMS} ${LDFORGE_LOCALES})
add_custom_target(translations ALL DEPENDS ${QM_FILES})
add_custom_target(resources ALL DEPENDS ${RESOURCE_FILES})
add_dependencies(resources translations)

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_CXX_EXTENSIONS OFF)
include_directories("${PROJECT_BINARY_DIR}")
include_directories("${PROJECT_BINARY_DIR}/src")
include_directories("${PROJECT_SOURCE_DIR}/src")
if (NOT MSVC)
	if ("${CMAKE_BUILD_TYPE}" STREQUAL "Debug" OR "${CMAKE_BUILD_TYPE}" STREQUAL "RelWithDebInfo")
		set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -DDEBUG")
	endif()
	set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall -Wextra")
	set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-implicit-fallthrough")
	set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-noexcept-type")
endif()
qt5_add_resources(LDFORGE_QRC ${LDFORGE_RESOURCES})
qt5_wrap_ui(LDFORGE_FORMS_HEADERS ${LDFORGE_FORMS})

# Move languages.qrc into the build directory to bake the .qm-files into LDForge
# so that they don't have to be shipped separately
# https://stackoverflow.com/a/34798124
set(LANGUAGES_QRC "languages.qrc")
configure_file(${LANGUAGES_QRC} ${LANGUAGES_QRC} COPYONLY)
qt5_add_resources(LDFORGE_QM_RC_FILE ${CMAKE_CURRENT_BINARY_DIR}/${LANGUAGES_QRC})

add_executable(ldforge WIN32
	${LDFORGE_SOURCES}
	${LDFORGE_HEADERS}
	${LDFORGE_RESOURCES}
	${LDFORGE_QRC}
	${LDFORGE_QM_RC_FILE}
	${LDFORGE_FORMS_HEADERS}
)

set_source_files_properties(${LDFORGE_HEADERS} PROPERTIES HEADER_FILE_ONLY TRUE)
set_source_files_properties(${LDFORGE_RESOURCES} PROPERTIES HEADER_FILE_ONLY TRUE)
set_target_properties(ldforge PROPERTIES AUTOMOC 1)
target_link_libraries(ldforge Qt5::Widgets Qt5::Network Qt5::OpenGL ${OPENGL_LIBRARIES})
cotire(ldforge)

# Collect the current hg revision into hginfo.h
add_custom_target(revision_check ALL
	COMMAND python3 "${CMAKE_SOURCE_DIR}/tools/updaterevision.py" --cwd "$(CMAKE_SOURCE_DIR)" hginfo.h
	WORKING_DIRECTORY ${CMAKE_BINARY_DIR})
add_dependencies(ldforge revision_check)

install(TARGETS ldforge RUNTIME DESTINATION bin)