Mercurial > zcinema / file revision

project (zcinema)
cmake_minimum_required (VERSION 2.6)

if (USE_QT5)
	find_package (Qt5Widgets REQUIRED)
	find_package (Qt5Core REQUIRED)
	find_package (Qt5OpenGL REQUIRED)
	find_package (Qt5Network REQUIRED)
	set (CMAKE_AUTOMOC ON)
else()
	find_package (Qt4 REQUIRED)
endif()

include_directories (${QT_INCLUDES} ${CMAKE_CURRENT_BINARY_DIR})

set (ZCINEMA_SOURCES
	src/demo.cpp
	src/main.cpp
	src/prompts.cpp
)

set (ZCINEMA_COMMON_SOURCES
	src-common/config.cpp
	src-common/misc.cpp
	src-common/version.cpp
)

set (ZCINEMA_CONFIG_SOURCES
	src-config/configwindow.cpp
	src-config/addversionprompt.cpp
	src-config/main.cpp
)

set (ZCINEMA_HEADERS
	src-common/config.h
	src-common/misc.h
	src-common/types.h
	src-common/version.h
	src-config/addversionprompt.h
	src-config/configwindow.h
	src/demo.h
	src/prompts.h
)

set (ZCINEMA_FORMS
	ui/findfile.ui
	ui/demoprompt.ui
	ui/unknownversion.ui
	ui/versionEditor.ui
	ui/configbox.ui
	ui/addversion.ui
)

set (ZCINEMA_RESOURCES zcinema.qrc)

if (NOT MSVC)
	set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++0x -W -Wall")
endif()

include_directories ("${PROJECT_BINARY_DIR}")
include_directories ("${PROJECT_SOURCE_DIR}/src")
include_directories ("${PROJECT_BINARY_DIR}/src")
include_directories ("${PROJECT_SOURCE_DIR}/src-common")
include_directories ("${PROJECT_BINARY_DIR}/src-common")
include_directories ("${PROJECT_SOURCE_DIR}/src-config")
include_directories ("${PROJECT_BINARY_DIR}/src-config")

if (USE_QT5)
	qt5_generate_moc (ZCINEMA_MOC ${ZCINEMA_HEADERS})
	qt5_add_resources (ZCINEMA_QRC ${ZCINEMA_RESOURCES})
	qt5_wrap_ui (ZCINEMA_FORMS_HEADERS ${ZCINEMA_FORMS})

	add_library (${PROJECT_NAME}-common STATIC
		${ZCINEMA_COMMON_SOURCES}
		${ZCINEMA_MOC}
		${ZCINEMA_QRC}
		${ZCINEMA_FORMS_HEADERS})
else()
	qt4_wrap_cpp (ZCINEMA_MOC ${ZCINEMA_HEADERS})
	qt4_wrap_ui (ZCINEMA_FORMS_HEADERS ${ZCINEMA_FORMS})
	qt4_add_resources (ZCINEMA_RCC ${ZCINEMA_RESOURCES})

	add_library (${PROJECT_NAME}-common STATIC
		${ZCINEMA_COMMON_SOURCES}
		${ZCINEMA_MOC}
		${ZCINEMA_RCC}
		${ZCINEMA_FORMS_HEADERS})
endif()

add_executable (${PROJECT_NAME} WIN32 ${ZCINEMA_SOURCES})
add_executable (${PROJECT_NAME}-config WIN32 ${ZCINEMA_CONFIG_SOURCES})

if (USE_QT5)
	target_link_libraries (${PROJECT_NAME}-common Qt5::Widgets)
else()
	target_link_libraries (${PROJECT_NAME}-common ${QT_QTCORE_LIBRARY} ${QT_QTGUI_LIBRARY})
endif()

target_link_libraries (${PROJECT_NAME} ${PROJECT_NAME}-common)
target_link_libraries (${PROJECT_NAME}-config ${PROJECT_NAME}-common)

add_custom_target (make_hginfo
	COMMAND python
		"${CMAKE_SOURCE_DIR}/updaterevision.py"
		"${CMAKE_CURRENT_BINARY_DIR}/hginfo.h"
	WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})

add_dependencies (${PROJECT_NAME}-common make_hginfo)

# With clang, we need to set -Wno-deprecated since Qt headers seem to use the register keyword
# which clang doesn't seem to like.
if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang")
	set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-deprecated")
endif()

install (TARGETS ${PROJECT_NAME} RUNTIME DESTINATION bin)